home *** CD-ROM | disk | FTP | other *** search
/ Linux Cubed Series 7: Sunsite / Linux Cubed Series 7 - Sunsite Vol 1.iso / libs / libelf-0.5 / libelf-0 / libelf-0.5.2 / aclocal.m4 < prev    next >
Encoding:
M4 Source File  |  1995-10-19  |  2.8 KB  |  97 lines
  1. # Local additions to Autoconf macros.
  2. # Copyright (C) 1995 Michael Riepe <riepe@ifwsn4.ifw.uni-hannover.de>
  3.  
  4. dnl mr_ACTION(VARIABLE [, ACTION-IF-YES [, ACTION-IF-NO ]])
  5. define([mr_ACTION], [
  6.   ifelse([$2$3], , , [
  7.     if test "$1" = yes; then
  8.       ifelse([$2], , :, [$2])
  9.     ifelse([$3], , , [else
  10.       $3])
  11.     fi
  12.   ])
  13. ])
  14.  
  15. dnl mr_SYS_ELFHOST([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  16. AC_DEFUN(mr_SYS_ELFHOST, [
  17.   AC_MSG_CHECKING([for ELF host system])
  18.   AC_CACHE_VAL(mr_cv_sys_elfhost, [
  19.     mr_cv_sys_elfhost=`sed -ne 's/^.ELF.*/yes/p' -e 'q' /bin/sh`
  20.     if test "$mr_cv_sys_elfhost" != 'yes'; then
  21.       mr_cv_sys_elfhost=no
  22.     fi
  23.   ])
  24.   AC_MSG_RESULT($mr_cv_sys_elfhost)
  25.   mr_ACTION([$mr_cv_sys_elfhost], [$1], [$2])
  26. ])
  27.  
  28. dnl mr_SYS_ELFTARGET([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  29. AC_DEFUN(mr_SYS_ELFTARGET, [
  30.   AC_MSG_CHECKING([for ELF target system])
  31.   AC_CACHE_VAL(mr_cv_sys_elftarget, [
  32.     rm -f conftest*
  33.     echo 'int main(){return 0;}' >conftest.c
  34.     if ! eval $ac_compile; then
  35.       AC_MSG_ERROR([cannot create object file])
  36.     fi
  37.     mr_cv_sys_elftarget=`sed -ne 's/^.ELF.*/yes/p' -e 'q' conftest.o`
  38.     if test "$mr_cv_sys_elftarget" != 'yes'; then
  39.       mr_cv_sys_elftarget=no
  40.     fi
  41.     rm -f conftest*
  42.   ])
  43.   AC_MSG_RESULT($mr_cv_sys_elftarget)
  44.   mr_ACTION([$mr_cv_sys_elftarget], [$1], [$2])
  45. ])
  46.  
  47. dnl mr_SYS_NLS_CATGETS([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  48. AC_DEFUN(mr_SYS_NLS_CATGETS, [
  49.   AC_MSG_CHECKING(for catgets)
  50.   AC_CACHE_VAL(mr_cv_sys_nls_catgets, [
  51.     AC_TRY_LINK(
  52.       [#include <nl_types.h>],
  53.       [catgets(catopen("",0),0,0,"");return 0;],
  54.       mr_cv_sys_nls_catgets=yes,
  55.       mr_cv_sys_nls_catgets=no)
  56.   ])
  57.   AC_MSG_RESULT($mr_cv_sys_nls_catgets)
  58.   mr_ACTION([$mr_cv_sys_nls_catgets], [$1], [$2])
  59. ])
  60.  
  61. dnl mr_SYS_NLS_GETTEXT([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  62. AC_DEFUN(mr_SYS_NLS_GETTEXT, [
  63.   AC_MSG_CHECKING(for gettext)
  64.   AC_CACHE_VAL(mr_cv_sys_nls_gettext, [
  65.     mr_save_libs="$LIBS"
  66.     LIBS="-lintl $LIBS"
  67.     AC_TRY_LINK(
  68.       [#include <libintl.h>],
  69.       [gettext("");return 0;],
  70.       mr_cv_sys_nls_gettext=yes,
  71.       mr_cv_sys_nls_gettext=no LIBS="$mr_save_libs")
  72.   ])
  73.   AC_MSG_RESULT($mr_cv_sys_nls_gettext)
  74.   mr_ACTION([$mr_cv_sys_nls_gettext], [$1], [$2])
  75. ])
  76.  
  77. dnl mr_SYS_NLS([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  78. AC_DEFUN(mr_SYS_NLS, [
  79.   AC_MSG_CHECKING(for NLS support)
  80.   AC_MSG_RESULT()
  81.   mr_sys_nls=no
  82.   mr_SYS_NLS_CATGETS(mr_sys_nls=yes)
  83.   mr_SYS_NLS_GETTEXT(mr_sys_nls=yes)
  84.   mr_ACTION([$mr_sys_nls], [$1], [$2])
  85. ])
  86.  
  87. dnl mr_ENABLE_NLS([ ACTION-IF-TRUE [, ACTION-IF-FALSE ]])
  88. AC_DEFUN(mr_ENABLE_NLS, [
  89.   AC_MSG_CHECKING(whether NLS is requested)
  90.   AC_ARG_ENABLE(nls,
  91.     [  --disable-nls           disable native language support],
  92.     [mr_enable_nls="$enableval"],
  93.     [mr_enable_nls=yes])
  94.   AC_MSG_RESULT($mr_enable_nls)
  95.   mr_ACTION([$mr_enable_nls], [$1], [$2])
  96. ])
  97.